Télécharger le fichier

'Visual Basic -Display a notifier dialog box
 
Option Explicit
On Error Resume Next
 
'------------------------------------------------------------------------------
' Checks the number of arguments
'------------------------------------------------------------------------------
Sub CheckArguments(nb)
    If WScript.Arguments.Count <> nb Then
        WScript.Echo "Need "& nb & "parameters, received " & WScript.Arguments.Count
        WScript.Quit
    End If
End Sub
 
'------------------------------------------------------------------------------
' Displays the message with the MS agent
'------------------------------------------------------------------------------
Function agentNotify(message)
    Dim objAgentCtl
    Dim strPfad
    Dim objAgent
    Dim strCharacter
 
    strCharacter = "Merlin"
 
    agentNotify = false
    Set objAgentCtl = WScript.CreateObject("Agent.Control.1", "objAgent_")
 
    If IsObject(objAgentCtl)  Then
        objAgentCtl.Connected = True
        strPfad = objShell.ExpandEnvironmentStrings("%WINDIR%\MSAgent\Chars\" & strCharacter & ".acs")
        objAgentCtl.Characters.Load strCharacter, strPfad
        Set objAgent = objAgentCtl.Characters(strCharacter)
        If isObject(objAgent) Then
            message = message & " . . . . . . . . . . . ."
            With objAgent
                .Show
                .Speak displayedString
                .Hide
            End With
            agentNotify = true
            WScript.Sleep 10000
        End If
    End If
End Function
 
'------------------------------------------------------------------------------
' Checks the number of arguments
'------------------------------------------------------------------------------
Function dialogNotify(message)
    Dim intSecondsToWait
    Dim strTitle
    Dim intButton
 
    intSecondsToWait = 7
    strTitle = "New mail"
    intButton = objShell.Popup(message, intSecondsToWait, strTitle, 0)
    dialogNotify = true
End Function
 
'==============================================================================
'==============================================================================
' Main Program
'==============================================================================
'==============================================================================
 
Dim objShell
 
Dim subject
Dim sender
Dim recipients
Dim size
Dim folder
Dim acctype
Dim accname
Dim body
Dim displayedString
 
Dim ret
 
 
CheckArguments 8
 
' Grab all of the arguments
 
subject = WScript.Arguments(0)
sender = WScript.Arguments(1)
recipients = WScript.Arguments(2)
size = WScript.Arguments(3)
folder = WScript.Arguments(4)
acctype = WScript.Arguments(5)
accname = WScript.Arguments(6)
body = WScript.Arguments(7)
 
displayedString = "From " & sender & ": " & vbCrLf & subject
 
Set objShell = WScript.CreateObject("WScript.Shell")
 
ret = agentNotify(displayedString)
If ret <> true Then
    ret = dialogNotify(displayedString)
End If